case

Оператор начинается с ключевого слова case и заканчивается ключевым словом endcase. Выражение в скобках будет вычислено один раз, после чего оно сравнивается со списком альтернатив в том порядке, в котором они записаны, и выполняются операторы, для которых альтернатива соответствует данному выражению.

Если ни один из элементов case не соответствует заданному выражению, выполняются инструкции внутри необязательный элемента default. Операторы case могут быть вложенными.

Синтаксис

case (<expression>)
  case_item1 :  <single statement>
  case_item2,
  case_item3 :  <single statement>
  case_item4 :  begin
                  <multiple statements>
                end
  default    : <statement>
endcase

Пример

module mux_(input [2:0]  a, b, c, input [1:0]  sel, output reg [2:0]  out); 
  always @(*) begin
    case(sel)
      2'b00   : out = a;     
      2'b01   : out = b;     
      2'b10   : out = c;     
      2'bz    : out = 3'bz;   
      2'bx    : out = 3'bx;   
      default : out = 0;     
    endcase
  end
endmodule

module case_tb;
  reg [2:0] aa, bb, cc, d;
  reg [1:0] sel;

  mux_ mux(aa, bb, cc, sel, d);
  initial begin
    $display("Time\t a \t b \t c \tout\tsel");
    $monitor("[%2t]\t%b\t%b\t%b\t%b\t%b", $time, aa, bb, cc, d, sel);
    #10 bb = 0; cc = 1;
    #10 sel = 0;
    #10 aa = 1;
    #10 sel = 1;
    #10 sel = 2;
    #10 cc = 2'bz;
    #10 sel = 5;
    #10 sel = 2;
    #10 sel = 2'bz;
    #10 sel = 2'bx;
  end
endmodule

Результат исполнения

Time     a   b   c  out sel
[ 0]    xxx xxx xxx xxx xx
[10]    xxx 000 001 xxx xx
[20]    xxx 000 001 xxx 00
[30]    001 000 001 001 00
[40]    001 000 001 000 01
[50]    001 000 001 001 10
[60]    001 000 0zz 0zz 10
[70]    001 000 0zz 000 01
[80]    001 000 0zz 0zz 10
[90]    001 000 0zz zzz zz
[100]   001 000 0zz xxx xx

casex/casez

Особые варианты case: casex и casez. Оба оператора используются для упрощения условных операторов за счет уменьшения количества принимаемых условных решений.

Ключевые различия:

• case : точное сравнение всех бит (1, 0, x, z)

• casez: игнорирует только z (1, 0, x)

• casex: игнорирует и x, и z (1, 0)

? – символ, обозначающий, что значение бита на указанной позиции может иметь любое значение.

Пример casex/casez/case

module cases;
  reg [3:0] my_input;
  reg [7:0] my_output;
  initial begin
    $monitor("[%02t] %04b %d", $time, my_input, my_output);
    my_input = 0;
    #15; my_input = 4'b000x; #1; $finish;
  end
  always @(my_input) begin
    case(my_input)
      4'b000? : my_output = 8'd0;
      4'b001? : my_output = 8'd1;
      4'b1??0 : my_output = 8'd2;
      4'b???x : my_output = 8'dx;
      default : my_output = 8'hFF;
    endcase
  end
  always #1 my_input++;
endmodule

Результат исполнения case	Результат исполнения casex	Результат исполнения casez
[00] 0000 255 [01] 0001 255 [02] 0010 255 [03] 0011 255 [04] 0100 255 [05] 0101 255 [06] 0110 255 [07] 0111 255 [08] 1000 255 [09] 1001 255 [10] 1010 255 [11] 1011 255 [12] 1100 255 [13] 1101 255 [14] 1110 255 [15] xxxx 255	[00] 0000 255 [01] 0001 255 [02] 0010 255 [03] 0011 255 [04] 0100 255 [05] 0101 255 [06] 0110 255 [07] 0111 255 [08] 1000 255 [09] 1001 255 [10] 1010 255 [11] 1011 255 [12] 1100 255 [02] 0010 1 [03] 0011 1 [04] 0100 x [05] 0101 x [06] 0110 x [07] 0111 x [08] 1000 2 [09] 1001 x [10] 1010 2 [11] 1011 x [12] 1100 2 [13] 1101 x [14] 1110 2 [15] xxxx 0	[00] 0000 0 [01] 0001 0 [02] 0010 1 [03] 0011 1 [04] 0100 255 [05] 0101 255 [06] 0110 255 [07] 0111 255 [08] 1000 2 [09] 1001 255 [10] 1010 2 [11] 1011 255 [12] 1100 2 [13] 1101 255 [14] 1110 2 [15] xxxx x

unique/priority

В SystemVerilog добавлены варианты unique и priority:

• unique-case

• unique0-case

• priority-case

Гарантирует, что ровно один вариант условия совпадает с выражением. Если совпадает более одного или ни одного - генерируется ошибка или предупреждение.

Аналогично unique-if и unique0-if unique0-case не генерирует предупреждения/ошибки.

module main;
   logic [1:0] counter = 2'b00;
   logic       clk = 1'b0;

   initial forever #1 clk <= ~clk;

   always @(posedge clk) begin
      counter <= counter + 2'd1;

      unique case (counter)
      2'd0: $display("case 0 [%0t] %d", $time, counter);
      2'd1: $display("case 1 [%0t] %d", $time, counter);
      4'b01: $display("case 1b [%0t] %d", $time, counter);
      2'd3: $display("case 3 [%0t] %d", $time, counter);
      endcase
      // 2'd2: отсутствует - будет warning/error

      if (counter == 2'd3) begin
         $display("PASSED");
         $finish(0);
      end
   end
endmodule

Результат исполнения unique-case

case 0 [1] 0
case 1 [3] 1
WARNING: test.sv:12: value is unhandled for priority or unique case statement
         Time: 5  Scope: main
case 3 [7] 3
PASSED

Результат исполнения unique0-case

case 0 [1] 0
case 1 [3] 1
case 3 [7] 3
PASSED

priority-case гарантирует, что хотя бы один вариант условия совпадает с выражением. Выполняется первый совпадающий вариант.

module main;
   logic [1:0] counter = 2'b00;
   logic       clk = 1'b0;

   initial forever #1 clk <= ~clk;

   always @(posedge clk) begin
      counter <= counter + 2'd1;

      priority case (counter)
            3'b1??: $display("case 3 [%0t] %d", $time, counter);
            3'b01?: $display("case 2 [%0t] %d", $time, counter);
            3'b001: $display("case 1 [%0t] %d", $time, counter);
      endcase

      if (counter == 2'd3) begin
         $display("PASSED");
         $finish(0);
      end
   end
endmodule

Результат исполнения priority-case

WARNING: test.sv:12: value is unhandled for priority or unique case statement
         Time: 1  Scope: main
case 1 [3] 1
WARNING: test.sv:12: value is unhandled for priority or unique case statement
         Time: 5  Scope: main
WARNING: test.sv:12: value is unhandled for priority or unique case statement
         Time: 7  Scope: main
PASSED

Результат исполнения case

case 1 [3] 1
PASSED